[心得分享] Windows 7 x64 免第三方工具檢視4K對齊 Cmd+vbs - SOGO論壇

@ECHO OFF&& SETLOCAL&& PUSHD "%~dp0"&& SETLOCAL ENABLEDELAYEDEXPANSION&& SETLOCAL ENABLEEXTENSIONS&& SET _V=5&& IF NOT "!_V!"=="5" (Echo DelayedExpansion Failed&& GOTO :EOF)
@Echo Off&& Title 4K對齊-SSD&& Color 9F&& Mode Con: Cols=80 Lines=30&& Cls
>"%temp%\tmp.vbs" Echo Wscript.Echo round(wscript.arguments(0)/wscript.arguments(1),2)
for /f "skip=1" %%i in ('wmic path Win32_LogicalDiskToPartition get StartingAddress') do (Set /a n+=1 & Set StartingAddress_!n!=%%i)
for %%i in (3,2) do (
for /f "tokens=1,2,3 delims= " %%a in ('wmic logicaldisk where "drivetype=%%i" get deviceid^,size^,freespace 2^>nul^|find ":"') do (
if %%i equ 3 (Echo.&& Echo.Disk %%a) Else (Echo.&& Echo.Usb Disk %%a)
Set /a n_2+=1
Call :calculate %%b 1073741824 availableGB
Call :calculate %%c 1073741824 allGB
for %%z in (!n_2!) do (Set StartingAddress=!StartingAddress_%%z!)
Call :calculate !StartingAddress! 4096 4K
if "!4k!"=="!4k:.=!" (Set 4k=是) Else (Set 4k=否)
Call :calculate !StartingAddress! 1048576 1M
if "!1m!"=="!1M:.=!" (Set 1m=是) Else (Set 1m=否)
Call :calculate !StartingAddress! 2097152 2M
if "!2m!"=="!2M:.=!" (Set 2m=是) Else (Set 2m=否)
Call :calculate !StartingAddress! 3145728 3M
if "!3m!"=="!3M:.=!" (Set 3m=是) Else (Set 3m=否)
Call :calculate !StartingAddress! 4194304 4M
if "!4m!"=="!4M:.=!" (Set 4m=是) Else (Set 4m=否)
Set availableGB= !availableGB!
Set allGB= !allGB!
Echo.總空間:!allGB:~-7!GB 可用:!availableGB:~-7!GB 4K(!4K!^) 1M(!1M!^) 2M(!2M!^) 3M(!3M!^) 4M(!4M!^)
Echo.
)
)
Del /F /A "%temp%\tmp.vbs">nul 2>&1 & Echo.&& Echo 完成:按任意鍵退出... & Pause>nul & Exit
:Calculate
for /f "Delims=" %%i in ('cscript //nologo %temp%\tmp.vbs %1 %2') do (Set %3=%%i)
Exit /b
Goto :Eof
REM ::::::::::::::::::::::::::::::::::::::::: REM
REM :: 記事本建議字型 : Consolas :: REM
REM :: 文書編輯推薦軟體 : NotePad++ :: REM
REM :: 副檔名建議 : FileName.Cmd :: REM
REM ::::::::::::::::::::::::::::::::::::::::: REM
:: 開啟記事本(NotePad)存入內容 "_任意名稱.Cmd" 副檔名為 .Cmd
:: 檔案名稱+下橫線 "_" 避免執行路徑上(%Path%)調用出錯建議...
:: 若使用NotePad++ 編輯批次檔設定 > 喜好設定 > 開新文件 > 編碼 > 請更換為 ANSI
:: 若使用NotePad 儲存檔案 > 另存新檔 : 雙引號 "_YourFileName.Cmd" > 存檔類型 : 所有檔案
:: !!! [提醒 : 微軟 .bat(不推薦) 或 .Cmd(命令指令碼) 編碼始終為 : ANSI ] !!!
:: 個人使用環境為 Windows 7 64位元其他環境未測試請斟酌使用...

複製代碼